نحوه اتصال NodeMCU V2 به ThingsConnect

مقدمه

NodeMCU یک برد توسعه بسیار محبوب است که به طور گسترده در دنیای اینترنت پیاده سازی شده است.
این برد بر اساس ماژول Wi-Fi ESP-12E است که با ترکیب عناصری آسان برنامه نویسی با Arduino IDE و قابلیت Wi-Fi، به طور کامل سازگار است.
پروژه های پروتوتایپ و توسعه را می توان به سهولت از طریق برنامه نویس داخلی و تراشه CP2102 USB-to-serial که ESP8266 را فلش می کند و خروجی سریال را با ادغام PC، مدیریت کرد. برد توسعه NodeMCU، ESP8266 را یکپارچه کرده است. این یک تراشه به خوبی یکپارچه شده است که به طور خاص برای پاسخگویی به نیازهای یک دنیای متصل جدید ساخته شده است.
این واحد امکان استفاده همزمان از برنامه را می دهد و یا تمام عملکردهای شبکه Wi-Fi را از یک واحد پردازش برنامه دیگر انتقال دهد.

در این راهنما، خواهیم آموخت که چگونه دستگاهی را در Thingsboard ایجاد کنیم، کتابخانه ها و ابزارهای مورد نیاز را نصب کنیم.
پس از آن، کد خود را تغییر داده و بر روی دستگاه بارگذاری کنیم و نتایج برنامه نویسی خود را بررسی کنیم و با استفاده از داشبورد وارد شده، داده ها را در ThingsBoard بررسی کنیم. دستگاه ما با استفاده از عملکردهای درخواست های مشترک و ویژگی های اشتراکی، با ThingsBoard همگام می شود.

الببته، ما قصد داریم دستگاه خود را با استفاده از قابلیت های ارائه شده مانند ویژگی های اشتراکی یا درخواست های RPC کنترل کنیم.

پیش نیازها

برای ادامه این راهنما، نیاز به موارد زیر داریم:

برد NodeMCU V2
محیط توسعه Arduino IDE
حساب ThingsBoard

ایجاد دستگاه در ThingsBoard

برای سادگی، ما دستگاه را به صورت دستی با استفاده از رابط کاربری ارائه می‌دهیم.

به نمونه ThingsBoard خود وارد شوید و به بخش “موجودیت‌ها” بروید. سپس روی صفحه “دستگاه‌ها” کلیک کنید.
روی آیکون “+” در گوشه بالا و راست جدول کلیک کرده و سپس “اضافه کردن دستگاه جدید” را انتخاب کنید.
نام دستگاه را وارد کنید. به عنوان مثال، “دستگاه من”. در این مرحله تغییرات دیگری لازم نیست. برای افزودن دستگاه، روی “افزودن” کلیک کنید.
دستگاه شما افزوده شده است.

//img

نصب کتابخانه‌ها و ابزارهای مورد نیاز

برای نصب برد در محیط توسعه Arduino IDE به مسیر File > Preferences بروید و URL زیر را به فیلد Additional Boards Manager URLs اضافه کنید.

http://arduino.esp8266.com/stable/package_esp8266com_index.json

//هImg

سپس به قسمت Tools > Board > Board Manager بروید و برد ESP8266 را نصب کنید.

ESP8266 را در قسمت جستجو قرار دهید و esp8266 را توسط انجمن Espressif نصب کنید.

//img

بعد از اتمام نصب، برد را از طریق منوی برد انتخاب کنید:
ابزارها > برد > ESP8266 > NodeMCU 1.0 (ماژول ESP-12E).

برای نصب ThingsBoard Arduino SDK، باید مراحل زیر را انجام دهید:

به تب “ابزارها” بروید و روی “مدیریت کتابخانه‌ها” کلیک کنید.
“ThingsBoard” را در جعبه جستجو قرار داده و برای کتابخانه یافت شده، دکمه “نصب” را فشار دهید.

//img

همچنین، برای بردهایی که بر پایه چیپ ESP8266 است، باید کتابخانه “mbedtls” را نصب کنیم.

در قسمت جستجوی کتابخانه، “mbetls” را وارد کرده و کتابخانه “Seeed_Arduino_mbedtls توسط Peter Yang” را نصب کنید.

//img

در این مرحله، همه کتابخانه‌ها و ابزارهای مورد نیاز را نصب کرده‌ایم.

اتصال دستگاه به ThingsConnect

برای اتصال دستگاه به ThingsBoard، نیازمند دریافت ابتدا اطلاعات اعتبار دستگاه هستیم. ThingsBoard از انواع مختلفی از اعتبارهای دستگاه پشتیبانی می‌کند. ما توصیه می‌کنیم از اعتبارهای پیش‌فرض و خودکار تولید شده استفاده کنید که یک توکن دسترسی برای این راهنما است.

روی ردیف دستگاه در جدول کلیک کنید تا جزئیات دستگاه را باز کنید.
روی “کپی توکن دسترسی” کلیک کنید. توکن به حافظه کلیپ‌بورد شما کپی خواهد شد. لطفاً آن را در یک مکان امن ذخیره کنید.

//img

حالا زمان برنامه‌ریزی برد برای اتصال به ThingsBoard فرا رسیده است.
برای این کار، می‌توانید از کد زیر استفاده کنید. این کد شامل تمام عملکردهای مورد نیاز برای این راهنما است.

#if defined(ESP8266)
  #include <ESP8266WiFi.h>
  #define THINGSBOARD_ENABLE_PROGMEM 0
#elif defined(ARDUINO_NANO_RP2040_CONNECT)
  #include <WiFiNINA_Generic.h>
#elif defined(ESP32) || defined(RASPBERRYPI_PICO) || defined(RASPBERRYPI_PICO_W)
  #include <WiFi.h>
  #include <WiFiClientSecure.h>
#endif

#define THINGSBOARD_ENABLE_PSRAM 0
#define THINGSBOARD_ENABLE_DYNAMIC 1

#ifndef LED_BUILTIN
#define LED_BUILTIN 99
#endif

#include <ThingsBoard.h>

constexpr char WIFI_SSID[] = "YOUR_WIFI_SSID";
constexpr char WIFI_PASSWORD[] = "YOUR_WIFI_PASSWORD";

// See https://thingsboard.io/docs/getting-started-guides/helloworld/
// to understand how to obtain an access token
constexpr char TOKEN[] = "YOUR_ACCESS_TOKEN";

// Thingsboard we want to establish a connection too
constexpr char THINGSBOARD_SERVER[] = "demo.thingsboard.io";
// MQTT port used to communicate with the server, 1883 is the default unencrypted MQTT port.
constexpr uint16_t THINGSBOARD_PORT = 1883U;

// Maximum size packets will ever be sent or received by the underlying MQTT client,
// if the size is to small messages might not be sent or received messages will be discarded
constexpr uint32_t MAX_MESSAGE_SIZE = 256U;

// Baud rate for the debugging serial connection.
// If the Serial output is mangled, ensure to change the monitor speed accordingly to this variable
constexpr uint32_t SERIAL_DEBUG_BAUD = 115200U;


// Initialize underlying client, used to establish a connection
WiFiClient wifiClient;
// Initialize ThingsBoard instance with the maximum needed buffer size
ThingsBoard tb(wifiClient, MAX_MESSAGE_SIZE);

// Attribute names for attribute request and attribute updates functionality

constexpr char BLINKING_INTERVAL_ATTR[] = "blinkingInterval";
constexpr char LED_MODE_ATTR[] = "ledMode";
constexpr char LED_STATE_ATTR[] = "ledState";

// Statuses for subscribing to rpc
bool subscribed = false;

// handle led state and mode changes
volatile bool attributesChanged = false;

// LED modes: 0 - continious state, 1 - blinking
volatile int ledMode = 0;

// Current led state
volatile bool ledState = false;

// Settings for interval in blinking mode
constexpr uint16_t BLINKING_INTERVAL_MS_MIN = 10U;
constexpr uint16_t BLINKING_INTERVAL_MS_MAX = 60000U;
volatile uint16_t blinkingInterval = 1000U;

uint32_t previousStateChange;

// For telemetry
constexpr int16_t telemetrySendInterval = 2000U;
uint32_t previousDataSend;

// List of shared attributes for subscribing to their updates
constexpr std::array<const char *, 2U> SHARED_ATTRIBUTES_LIST = {
  LED_STATE_ATTR,
  BLINKING_INTERVAL_ATTR
};

// List of client attributes for requesting them (Using to initialize device states)
constexpr std::array<const char *, 1U> CLIENT_ATTRIBUTES_LIST = {
  LED_MODE_ATTR
};

/// @brief Initalizes WiFi connection,
// will endlessly delay until a connection has been successfully established
void InitWiFi() {
  Serial.println("Connecting to AP ...");
  // Attempting to establish a connection to the given WiFi network
  WiFi.begin(WIFI_SSID, WIFI_PASSWORD);
  while (WiFi.status() != WL_CONNECTED) {
    // Delay 500ms until a connection has been succesfully established
    delay(500);
    Serial.print(".");
  }
  Serial.println("Connected to AP");
}

/// @brief Reconnects the WiFi uses InitWiFi if the connection has been removed
/// @return Returns true as soon as a connection has been established again
const bool reconnect() {
  // Check to ensure we aren't connected yet
  const wl_status_t status = WiFi.status();
  if (status == WL_CONNECTED) {
    return true;
  }

  // If we aren't establish a new connection to the given WiFi network
  InitWiFi();
  return true;
}


/// @brief Processes function for RPC call "setLedMode"
/// RPC_Data is a JSON variant, that can be queried using operator[]
/// See https://arduinojson.org/v5/api/jsonvariant/subscript/ for more details
/// @param data Data containing the rpc data that was called and its current value
/// @return Response that should be sent to the cloud. Useful for getMethods
RPC_Response processSetLedMode(const RPC_Data &data) {
  Serial.println("Received the set led state RPC method");

  // Process data
  int new_mode = data;

  Serial.print("Mode to change: ");
  Serial.println(new_mode);

  if (new_mode != 0 && new_mode != 1) {
    return RPC_Response("error", "Unknown mode!");
  }

  ledMode = new_mode;

  attributesChanged = true;

  // Returning current mode
  return RPC_Response("newMode", (int)ledMode);
}


// Optional, keep subscribed shared attributes empty instead,
// and the callback will be called for every shared attribute changed on the device,
// instead of only the one that were entered instead
const std::array<RPC_Callback, 1U> callbacks = {
  RPC_Callback{ "setLedMode", processSetLedMode }
};


/// @brief Update callback that will be called as soon as one of the provided shared attributes changes value,
/// if none are provided we subscribe to any shared attribute change instead
/// @param data Data containing the shared attributes that were changed and their current value
void processSharedAttributes(const Shared_Attribute_Data &data) {
  for (auto it = data.begin(); it != data.end(); ++it) {
    if (strcmp(it->key().c_str(), BLINKING_INTERVAL_ATTR) == 0) {
      const uint16_t new_interval = it->value().as<uint16_t>();
      if (new_interval >= BLINKING_INTERVAL_MS_MIN && new_interval <= BLINKING_INTERVAL_MS_MAX) {
        blinkingInterval = new_interval;
        Serial.print("Updated blinking interval to: ");
        Serial.println(new_interval);
      }
    } else if(strcmp(it->key().c_str(), LED_STATE_ATTR) == 0) {
      ledState = it->value().as<bool>();
      digitalWrite(LED_BUILTIN, ledState ? HIGH : LOW);
      Serial.print("Updated state to: ");
      Serial.println(ledState);
    }
  }
  attributesChanged = true;
}

void processClientAttributes(const Shared_Attribute_Data &data) {
  for (auto it = data.begin(); it != data.end(); ++it) {
    if (strcmp(it->key().c_str(), LED_MODE_ATTR) == 0) {
      const uint16_t new_mode = it->value().as<uint16_t>();
      ledMode = new_mode;
    }
  }
}

const Shared_Attribute_Callback attributes_callback(SHARED_ATTRIBUTES_LIST.cbegin(), SHARED_ATTRIBUTES_LIST.cend(), &processSharedAttributes);
const Attribute_Request_Callback attribute_shared_request_callback(SHARED_ATTRIBUTES_LIST.cbegin(), SHARED_ATTRIBUTES_LIST.cend(), &processSharedAttributes);
const Attribute_Request_Callback attribute_client_request_callback(CLIENT_ATTRIBUTES_LIST.cbegin(), CLIENT_ATTRIBUTES_LIST.cend(), &processClientAttributes);

void setup() {
  // Initalize serial connection for debugging
  Serial.begin(115200);
  pinMode(LED_BUILTIN, OUTPUT);
  delay(1000);
  InitWiFi();
}

void loop() {
//  delay(10);

  if (!reconnect()) {
    subscribed = false;
    return;
  }

  if (!tb.connected()) {
    subscribed = false;
    // Connect to the ThingsBoard
    Serial.print("Connecting to: ");
    Serial.print(THINGSBOARD_SERVER);
    Serial.print(" with token ");
    Serial.println(TOKEN);
    if (!tb.connect(THINGSBOARD_SERVER, TOKEN, THINGSBOARD_PORT)) {
      Serial.println("Failed to connect");
      return;
    }
    // Sending a MAC address as an attribute
    tb.sendAttributeString("macAddress", WiFi.macAddress().c_str());
  }

  if (!subscribed) {
    Serial.println("Subscribing for RPC...");
    // Perform a subscription. All consequent data processing will happen in
    // processSetLedState() and processSetLedMode() functions,
    // as denoted by callbacks array.
    if (!tb.RPC_Subscribe(callbacks.cbegin(), callbacks.cend())) {
      Serial.println("Failed to subscribe for RPC");
      return;
    }

    if (!tb.Shared_Attributes_Subscribe(attributes_callback)) {
      Serial.println("Failed to subscribe for shared attribute updates");
      return;
    }

    Serial.println("Subscribe done");
    subscribed = true;

    // Request current states of shared attributes
    if (!tb.Shared_Attributes_Request(attribute_shared_request_callback)) {
      Serial.println("Failed to request for shared attributes");
      return;
    }

    // Request current states of client attributes
    if (!tb.Client_Attributes_Request(attribute_client_request_callback)) {
      Serial.println("Failed to request for client attributes");
      return;
    }
  }

  if (attributesChanged) {
    attributesChanged = false;
    if (ledMode == 0) {
      previousStateChange = millis();
    }
    tb.sendTelemetryInt(LED_MODE_ATTR, ledMode);
    tb.sendTelemetryBool(LED_STATE_ATTR, ledState);
    tb.sendAttributeInt(LED_MODE_ATTR, ledMode);
    tb.sendAttributeBool(LED_STATE_ATTR, ledState);
  }

  if (ledMode == 1 && millis() - previousStateChange > blinkingInterval) {
    previousStateChange = millis();
    ledState = !ledState;
    digitalWrite(LED_BUILTIN, ledState);
    tb.sendTelemetryBool(LED_STATE_ATTR, ledState);
    tb.sendAttributeBool(LED_STATE_ATTR, ledState);
    if (LED_BUILTIN == 99) {
      Serial.print("LED state changed to: ");
      Serial.println(ledState);
    }
  }

  // Sending telemetry every telemetrySendInterval time
  if (millis() - previousDataSend > telemetrySendInterval) {
    previousDataSend = millis();
    tb.sendTelemetryInt("temperature", random(10, 20));
    tb.sendAttributeInt("rssi", WiFi.RSSI());
    tb.sendAttributeInt("channel", WiFi.channel());
    tb.sendAttributeString("bssid", WiFi.BSSIDstr().c_str());
    tb.sendAttributeString("localIp", WiFi.localIP().toString().c_str());
    tb.sendAttributeString("ssid", WiFi.SSID().c_str());
  }

  tb.loop();
}

در کد، متغیرهایی را با SSID شبکه WiFi، رمز عبور، رمز دسترسی دستگاه ThingsBoard خود جایگزین کنید.

متغیرهای لازم برای اتصال:

//جدول

...

constexpr char WIFI_SSID[] = "YOUR_WIFI_SSID";
constexpr char WIFI_PASSWORD[] = "YOUR_WIFI_PASSWORD";

constexpr char TOKEN[] = "YOUR_ACCESS_TOKEN";

constexpr char THINGSBOARD_SERVER[] = "demo.thingsboard.io";
constexpr uint16_t THINGSBOARD_PORT = 1883U;

constexpr uint32_t MAX_MESSAGE_SIZE = 256U;
constexpr uint32_t SERIAL_DEBUG_BAUD = 115200U;

...

بخش ارسال داده (به طور پیش فرض، نمونه مقدار تصادفی برای کلید دما و برخی اطلاعات WiFi را ارسال می‌کند):

...
    tb.sendTelemetryInt("temperature", random(10, 20));
    tb.sendAttributeInt("rssi", WiFi.RSSI());
    tb.sendAttributeString("bssid", WiFi.BSSIDstr().c_str());
    tb.sendAttributeString("localIp", WiFi.localIP().toString().c_str());
    tb.sendAttributeString("ssid", WiFi.SSID().c_str());
    tb.sendAttributeInt("channel", WiFi.channel());
...

سپس با فشار دادن دکمه “آپلود” یا ترکیب کلیدهای Ctrl+U، کد را به دستگاه بارگذاری کنید.

//Img

اگر نمی توانید کد را آپلود کنید و یک خطا دریافت می کنید: ویژگی “upload.tool.serial” تعریف نشده است، می توانید کارهای زیر را انجام دهید:

به “Tools” > “Programmer” بروید و “Esptool” را به عنوان برنامه نویس انتخاب کنید.
به «اسکچ» > «آپلود با استفاده از برنامه نویس» بروید.

//img

بررسی داده ها در ThingsConnect

برای بررسی داده ها و دریافت توانایی ارسال دستورات یا داده ها به دستگاه، داشبورد را ایجاد می کنیم.

ابتدا فایل داشبورد داده های دستگاه بررسی و کنترل را دانلود کنید.

برای افزودن داشبورد به ThingsBoard باید آن را وارد کنیم و برای این کار باید مراحل زیر را طی کنیم:

از طریق منوی اصلی در سمت چپ صفحه به داشبوردها بروید.
روی دکمه “+” در گوشه سمت راست بالای صفحه کلیک کنید و “وارد کردن داشبورد” را انتخاب کنید.
فایل dashboard.json خود را انتخاب کنید و دکمه import را فشار دهید.
اکنون می توانید داشبورد وارد شده را در جدول مشاهده کنید.

//img

پس از وارد کردن، باید برای دستگاه خود نام مستعار (Alias) انتخاب کنیم.
برای این کار، باید روی آیکون قلم مورد نظر کلیک کرده و “مستعارهای entity” را انتخاب کنید، سپس مستعار “دستگاه من” را انتخاب کرده و با فشار دادن آیکون قلم، آن را برای ویرایش باز کنید.
سپس یک دستگاه با نام “دستگاه من” را از لیست کشویی انتخاب کنید و مستعار entity را ذخیره کنید. حالا باید قادر باشید داده‌ها را از دستگاه مشاهده کنید.

برای بررسی داده‌ها از دستگاه خود، باید داشبورد وارد شده را باز کنید:

با کلیک بر روی داشبورد در جدول، آن را باز کنید.
مشاهده‌ی داشبورد برای بررسی داده و کنترل دستگاه.
دریافت ویژگی‌ها (attributes) از دستگاه.
اطلاعات دستگاه از سرور ThingsBoard.
ابزارک برای مشاهده تاریخچه تغییرات حالت LED.
ابزارک برای مشاهده تاریخچه دمای شبیه‌سازی شده.

//img

همگام‌سازی وضعیت دستگاه با استفاده از درخواست‌های کلاینت و ویژگی‌های مشترک

برای دریافت وضعیت دستگاه از ThingsBoard در زمان راه‌اندازی، قابلیتی برای انجام این کار در کد وجود دارد.
بخش‌های مسئول کد نمونه:

تماس‌های بازگشت ویژگی‌ها (Attribute callbacks):

...
void processSharedAttributes(const Shared_Attribute_Data &data) {
  for (auto it = data.begin(); it != data.end(); ++it) {
    if (strcmp(it->key().c_str(), BLINKING_INTERVAL_ATTR) == 0) {
      const uint16_t new_interval = it->value().as<uint16_t>();
      if (new_interval >= BLINKING_INTERVAL_MS_MIN && new_interval <= BLINKING_INTERVAL_MS_MAX) {
        blinkingInterval = new_interval;
        Serial.print("Updated blinking interval to: ");
        Serial.println(new_interval);
      }
    } else if(strcmp(it->key().c_str(), LED_STATE_ATTR) == 0) {
      ledState = it->value().as<bool>();
      digitalWrite(LED_BUILTIN, ledState ? HIGH : LOW);
      Serial.print("Updated state to: ");
      Serial.println(ledState);
    }
  }
  attributesChanged = true;
}

void processClientAttributes(const Shared_Attribute_Data &data) {
  for (auto it = data.begin(); it != data.end(); ++it) {
    if (strcmp(it->key().c_str(), LED_MODE_ATTR) == 0) {
      const uint16_t new_mode = it->value().as<uint16_t>();
      ledMode = new_mode;
    }
  }
}
...
const Attribute_Request_Callback attribute_shared_request_callback(SHARED_ATTRIBUTES_LIST.cbegin(), SHARED_ATTRIBUTES_LIST.cend(), &processSharedAttributes);
const Attribute_Request_Callback attribute_client_request_callback(CLIENT_ATTRIBUTES_LIST.cbegin(), CLIENT_ATTRIBUTES_LIST.cend(), &processClientAttributes);
...

همانطور که می‌بینید، ما دو تماس بازگشتی داریم، اولین تماس بازگشتی برای ویژگی‌های مشترک و دومین تماس بازگشتی برای ویژگی‌های مشتری است.
اولین تماس بازگشتی پاسخی با فاصله زمانی چشمک زدن دریافت می‌کند تا با تنظیم دوره مناسب برای چشمک زدن استفاده شود.
تماس بازگشتی دومین ویژگی حالت و وضعیت LED را دریافت می‌کند تا آنها را ذخیره کرده و تنظیم کند.
این قابلیت به ما اجازه می‌دهد که پس از راه‌اندازی مجدد وضعیت فعلی را حفظ کنیم.

درخواست‌های ویژگی:

...
  // Request current states of shared attributes
  if (!tb.Shared_Attributes_Request(attribute_shared_request_callback)) {
    Serial.println("Failed to request for shared attributes");
    return;
  }

  // Request current states of client attributes
  if (!tb.Client_Attributes_Request(attribute_client_request_callback)) {
    Serial.println("Failed to request for client attributes");
    return;
  }
...

برای اینکه تماس‌های بازگشتی ما داده را دریافت کنند، باید یک درخواست به ThingsBoard ارسال کنیم.

کنترل دستگاه با استفاده از ویژگی های مشترک

همچنین، ما می‌توانیم با استفاده از قابلیت به‌روزرسانی ویژگی‌های مشترک، دوره چشمک‌زنی را تغییر دهیم.

برای تغییر دوره چشمک‌زنی، فقط کافی است مقدار مربوطه را در داشبورد خود تغییر دهیم.
بعد از اعمال تغییر با فشار دادن علامت تیک، یک پیام تأیید را خواهید دید.

//img

برای تغییر وضعیت وقتی که چشمک‌زنی غیرفعال شده است، می‌توانیم از سوئیچ موجود در همان ویجت استفاده کنیم:

این کار فقط زمانی امکان پذیر است که حالت چشمک‌زنی غیرفعال شده باشد.

///img

برای دستیابی به این مورد، ما یک متغیر به نام “blinkingInterval” داریم که در بخش‌های زیر از کد استفاده می‌شود:

کالبک برای به‌روزرسانی ویژگی‌های مشترک:

...

void processSharedAttributes(const Shared_Attribute_Data &data) {
  for (auto it = data.begin(); it != data.end(); ++it) {
    if (strcmp(it->key().c_str(), BLINKING_INTERVAL_ATTR) == 0) {
      const uint16_t new_interval = it->value().as<uint16_t>();
      if (new_interval >= BLINKING_INTERVAL_MS_MIN && new_interval <= BLINKING_INTERVAL_MS_MAX) {
        blinkingInterval = new_interval;
        Serial.print("Updated blinking interval to: ");
        Serial.println(new_interval);
      }
    } else if(strcmp(it->key().c_str(), LED_STATE_ATTR) == 0) {
      ledState = it->value().as<bool>();
      digitalWrite(LED_BUILTIN, ledState ? HIGH : LOW);
      Serial.print("Updated state to: ");
      Serial.println(ledState);
    }
  }
  attributesChanged = true;
}

...
const Shared_Attribute_Callback attributes_callback(SHARED_ATTRIBUTES_LIST.cbegin(), SHARED_ATTRIBUTES_LIST.cend(), &processSharedAttributes);
...

مشترک شدن برای به‌روزرسانی ویژگی‌های مشترک:

...
    if (!tb.Shared_Attributes_Request(attribute_shared_request_callback)) {
      Serial.println("Failed to request for shared attributes");
      return;
    }
...

بخشی از کد برای چشمک زدن:

...

  if (ledMode == 1 && millis() - previousStateChange > blinkingInterval) {
    previousStateChange = millis();
    ledState = !ledState;
    digitalWrite(LED_BUILTIN, ledState);
    tb.sendTelemetryBool(LED_STATE_ATTR, ledState);
    tb.sendAttributeBool(LED_STATE_ATTR, ledState);
    if (LED_BUILTIN == 99) {
      Serial.print("LED state changed to: ");
      Serial.println(ledState);
    }
  }
...

شما می‌توانید منطق را تغییر دهید تا به اهداف خود برسید و پردازشی برای ویژگی‌های خود اضافه کنید.

کنترل دستگاه با استفاده از RPC

شما می‌توانید به طور دستی وضعیت راه‌اندازی LED را تغییر دهید و حالت بین روشنایی مداوم و چشمک زنی را تغییر دهید. برای این کار، می‌توانید از بخش‌های زیر در داشبورد ما استفاده کنید:

برای تغییر وضعیت روشنایی LED به حالت مداوم، از ویجت سوئیچ استفاده کنید.
برای تغییر وضعیت روشنایی LED به حالت چشمک زنی، از ویجت سوئیچ گرد استفاده کنید.

//img

لطفاً توجه کنید که شما تنها می‌توانید وضعیت LED را تغییر دهید اگر حالت چشمک‌زنی غیرفعال باشد.

در نمونه کد، قابلیت بررسی و اجرای دستورات RPC وجود دارد.
برای امکان کنترل دستگاه، از بخش‌های زیر در کد استفاده کرده‌ایم:

کالبک برای درخواست‌های RPC:

...

RPC_Response processSetLedMode(const RPC_Data &data) {
  Serial.println("Received the set led state RPC method");

  // Process data
  int new_mode = data;

  Serial.print("Mode to change: ");
  Serial.println(new_mode);

  if (new_mode != 0 && new_mode != 1) {
    return RPC_Response("error", "Unknown mode!");
  }

  ledMode = new_mode;

  attributesChanged = true;

  // Returning current mode
  return RPC_Response("newMode", (int)ledMode);
}

...

const std::array<RPC_Callback, 1U> callbacks = {
  RPC_Callback{ "setLedMode", processSetLedMode }
};

...

مشترک شدن برای درخواست‌های RPC:

...
    if (!tb.RPC_Subscribe(callbacks.cbegin(), callbacks.cend())) {
      Serial.println("Failed to subscribe for RPC");
      return;
    }
...

می‌توانید کد را تغییر دهید تا به اهداف خود برسید و پردازشی برای دستورات RPC اضافه کنید.

نتیجه

با دانش بیان شده در این راهنما، می توانید به راحتی NodeMCU V2 خود را متصل کرده و داده ها را به ThingsBoard ارسال کنید.

برای کسب اطلاعات بیشتر در مورد مفاهیم و ویژگی های کلیدی، اسناد پلت فرم را کاوش کنید. به عنوان مثال، قوانین هشدار یا داشبورد را پیکربندی کنید.

پنل IOT

نرم افزار موبایل

سخت افزار

فروش پنل

انرژی هوشمند

کشاورزی هوشمند

ردیابی ناوگان

اندازه گیری هوشمند

پایش کیفیت هوا

مدیریت پسماند

نظارت بر محیط زیست

دفتر هوشمند

اندازه گیری آب

خرده فروشی هوشمند

آبیاری هوشمند

تولید سخت افزار

توزیع کننده و نماینده ها

فروشگاه

درباره ما

فرم تماس با ما

نحوه اتصال NodeMCU V2 به ThingsConnect

مقدمه

پیش نیازها

ایجاد دستگاه در ThingsBoard

نصب کتابخانه‌ها و ابزارهای مورد نیاز

اتصال دستگاه به ThingsConnect

بررسی داده ها در ThingsConnect

همگام‌سازی وضعیت دستگاه با استفاده از درخواست‌های کلاینت و ویژگی‌های مشترک

کنترل دستگاه با استفاده از ویژگی های مشترک

کنترل دستگاه با استفاده از RPC

نتیجه

عناوین هر بخش

اسناد سامانه اتصال اشیاء